zion/modules/periodic.nix

{ config, lib, pkgs, ... }:

let
  stateDir = "/var/lib/dnsmasq";
  blocklist = "${stateDir}/dnsmasq.blacklist.txt";

in {
  # PostgreSQL daily backups
  services.postgresqlBackup = {
    enable = true;
    backupAll = true;
    location = "/vault/backups/zion/databases";
    startAt = "*-*-* 05:15:00";
  };

  # Fetch hosts-blocklists daily
  systemd.services.download-dns-blocklist = {
    description = "Download hosts-blocklists";
    wantedBy = [ "default.target" ];
    path = with pkgs; [ curl coreutils ];
    script = ''
      curl -L https://github.com/notracking/hosts-blocklists/raw/master/dnsmasq/dnsmasq.blacklist.txt -o ${blocklist}
      sed "/cainiao/d" -i ${blocklist}
    '';
    serviceConfig.Type = "oneshot";
    postStop = ''
      chown -R dnsmasq ${stateDir}
      systemctl restart dnsmasq
    '';
    after = [ "wireguard-wg0.service" ];
    startAt = "02:00:00";
  };

  # Enable SATA HAT
  systemd.services.sata-hat = {
    description = "Enable software support for SATA Hat";
    wantedBy = [ "zfs-import.target" ];
    script = ''
      ${pkgs.bash}/bin/bash -c "/home/coolneng/system/scripts/SATA-hat.sh on"
    '';
    serviceConfig = {
      Type = "oneshot";
      RemainAfterExit = "yes";
      ExecStop = ''
        ${pkgs.bash}/bin/bash -c "/home/coolneng/system/scripts/SATA-hat.sh off"
      '';
    };
    before = [ "zfs-import.target" "zfs-import-vault.service" "umount.target" ];
    requires = [ "systemd-udev-settle.service" ];
    after = [ "systemd-udev-settle.service" ];
    conflicts = [ "umount.target" ];
    requiredBy = [ "syncthing.service" "radicale.service" "gitea.service" ];
  };

  # HACK: restart services dependent on ZFS afer mount
  systemd.services.restart-services-mount = {
    description = "Restart services after the ZFS dataset is mounted";
    wantedBy = [ "default.target" ];
    script = ''
      sleep 5
      systemctl restart syncthing
      systemctl restart radicale
      systemctl restart gitea
      systemctl restart podman-openbooks
      systemctl restart podman-mqtt2prometheus
      systemctl restart podman-mongodb
      systemctl restart podman-nightscout
    '';
    serviceConfig.Type = "oneshot";
    requires = [ "sata-hat.service" ];
    after = [ "vault.mount" ];
  };

  # Idle HDDs when not used
  systemd.services.hd-idle = {
    description = "Idle HDDs when not in use";
    wantedBy = [ "default.target" ];
    path = with pkgs; [ hd-idle ];
    script = "${pkgs.hd-idle}/bin/hd-idle";
    serviceConfig.Type = "simple";
    requires = [ "sata-hat.service" ];
    after = [ "vault.mount" ];
  };

  # Push zion changes to git daily
  systemd.user.services.zion-push = {
    description = "Push zion changes to git";
    wantedBy = [ "default.target" ];
    path = with pkgs; [ git ];
    script = ''
      ${pkgs.git}/bin/git -C /home/coolneng/system pull
      ${pkgs.git}/bin/git -C /home/coolneng/system push
    '';
    serviceConfig.Type = "oneshot";
    startAt = "07:00:00";
    after = [ "network-online.target" ];
  };
}